From: Andrea Zagli <azagli@libero.it>
Date: Sun, 23 Aug 2015 07:26:42 +0000 (+0200)
Subject: libgrss: nuovo pacchetto wip.
X-Git-Url: https://saetta.ns0.it/gitweb?a=commitdiff_plain;h=58bb9a95711bf052e59c10736eefd4573c7c8aba;p=msys2

libgrss: nuovo pacchetto wip.
---

diff --git a/packages/mingw-w64-libgrss/001-win.patch b/packages/mingw-w64-libgrss/001-win.patch
new file mode 100644
index 0000000..46b4760
--- /dev/null
+++ b/packages/mingw-w64-libgrss/001-win.patch
@@ -0,0 +1,11 @@
+--- ./src/utils.h.orig	2015-08-23 09:18:10.822924600 +0200
++++ ./src/utils.h	2015-08-23 09:18:26.588310400 +0200
+@@ -34,8 +34,6 @@
+ #include <errno.h>
+ #include <sys/types.h>
+ #include <sys/stat.h>
+-#include <arpa/inet.h>
+-#include <netinet/in.h>
+ 
+ #include "libgrss.h"
+ 
diff --git a/packages/mingw-w64-libgrss/PKGBUILD b/packages/mingw-w64-libgrss/PKGBUILD
new file mode 100644
index 0000000..c5ea646
--- /dev/null
+++ b/packages/mingw-w64-libgrss/PKGBUILD
@@ -0,0 +1,61 @@
+# Maintainer: Andrea Zagli <andrea.zagli.free@gmail.com>
+
+_realname=libgrss
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=0.7.0
+pkgrel=1
+arch=('any')
+pkgdesc="A Glib-based library to manage RSS and Atom feeds (mingw-w64)"
+depends=("${MINGW_PACKAGE_PREFIX}-glib2"
+         "${MINGW_PACKAGE_PREFIX}-gtk3"
+         "${MINGW_PACKAGE_PREFIX}-cairo"
+         "${MINGW_PACKAGE_PREFIX}-lcms2"
+         "${MINGW_PACKAGE_PREFIX}-libarchive"
+         "${MINGW_PACKAGE_PREFIX}-libjpeg"
+         "${MINGW_PACKAGE_PREFIX}-libxslt"
+         "${MINGW_PACKAGE_PREFIX}-libpng")
+makedepends=("${MINGW_PACKAGE_PREFIX}-gcc"
+             "${MINGW_PACKAGE_PREFIX}-pkg-config"
+             "make"
+             "intltool"
+             "gettext-devel")
+options=('strip' 'staticlibs')
+license=("LGPL 2.1")
+url="http://www.gnome.org"
+source=(http://ftp.gnome.org/pub/gnome/sources/${_realname}/${pkgver:0:3}/${_realname}-${pkgver}.tar.xz
+        001-win.patch)
+sha256sums=('6709c0f630a915ea7d5f1ac88ac173ef974d8d7406f43bd4be70d3e71fd554d9'
+            '9965979ea78b5bcdee6d5442b1273d27dba70f55e6f9adb0219a54b7e78dfd61')
+
+prepare() {
+  cd ${_realname}-${pkgver}
+  patch -p1 -i ${srcdir}/001-win.patch
+
+  autoreconf -fi
+}
+
+build() {
+  [[ -d build-${MINGW_CHOST} ]] && rm -rf build-${MINGW_CHOST}
+  mkdir -p build-${MINGW_CHOST}
+  cd build-${MINGW_CHOST}
+
+  mkdir -p doc/reference/html
+  cp -rf ../${_realname}-${pkgver}/doc/reference/html/* doc/reference/html
+
+  ../${_realname}-${pkgver}/configure \
+    --host=${MINGW_CHOST} \
+    --target=${MINGW_CHOST} \
+    --build=${MINGW_CHOST} \
+    --prefix=${MINGW_PREFIX} \
+    --libexecdir=${MINGW_PREFIX}/lib
+
+  make
+}
+
+package() {
+  cd "${srcdir}/build-${MINGW_CHOST}"
+  make DESTDIR=${pkgdir} install
+
+  install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING"
+}