libzakgtkdecodergdaexqe: nuovo pacchetto.

diff --git a/packages/mingw-w64-libzakgtkdecodergdaexqe/.gitignore b/packages/mingw-w64-libzakgtkdecodergdaexqe/.gitignore
new file mode 100644 (file)
index 0000000..44381d1
--- /dev/null
+++ b/packages/mingw-w64-libzakgtkdecodergdaexqe/.gitignore
@@ -0,0 +1 @@
+libzakgtkdecodergdaexqe

diff --git a/packages/mingw-w64-libzakgtkdecodergdaexqe/001-path.patch b/packages/mingw-w64-libzakgtkdecodergdaexqe/001-path.patch
new file mode 100644 (file)
index 0000000..c27a19c
--- /dev/null
+++ b/packages/mingw-w64-libzakgtkdecodergdaexqe/001-path.patch
@@ -0,0 +1,25 @@
+--- ./src/Makefile.am.orig     2016-01-13 11:56:04.615820700 +0100
++++ ./src/Makefile.am  2016-01-13 11:58:15.980095300 +0100
+@@ -6,7 +6,8 @@
+ libmodulesdir = $(libdir)
+ endif
+ 
+-libgdaexmodulesdir = `pkg-config --variable=modulesdir libgdaex`
++modsdir = $(shell pkg-config --variable=modulesdir libgdaex)
++libgdaexmodulesdir = $(shell cygpath $(modsdir))
+ 
+ LIBS = $(ZAKGTKDECODERGDAEXQE_LIBS)
+ 
+@@ -28,8 +29,9 @@
+ libzakgtkdecodergdaexqe_includedir = $(includedir)/libzakgtkdecodergdaexqe
+ 
+ install-exec-hook:
+-      cd $(libgdaexmodulesdir) && \
+-      ln -s -f $(libmodulesdir)/libzakgtkdecodergdaexqe$(libmodulesext) .
++      mkdir -p $(DESTDIR)$(libgdaexmodulesdir) && \
++      cd $(DESTDIR)$(libgdaexmodulesdir) && \
++      ln -s -f $(DESTDIR)$(libmodulesdir)/libzakgtkdecodergdaexqe$(libmodulesext) .
+ 
+ uninstall-hook:
+-      rm -f $(libgdaexmodulesdir)/libzakgtkdecodergdaexqe$(libmodulesext)
++      rm -f $(DESTDIR)$(libgdaexmodulesdir)/libzakgtkdecodergdaexqe$(libmodulesext)

diff --git a/packages/mingw-w64-libzakgtkdecodergdaexqe/PKGBUILD b/packages/mingw-w64-libzakgtkdecodergdaexqe/PKGBUILD
new file mode 100644 (file)
index 0000000..ce9a8ae
--- /dev/null
+++ b/packages/mingw-w64-libzakgtkdecodergdaexqe/PKGBUILD
@@ -0,0 +1,52 @@
+# Maintainer: Andrea Zagli <andrea.zagli.free@gmail.com>
+
+_realname=libzakgtkdecodergdaexqe
+_base_ver=0.0.1
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=0.0.1.2.7b1a243
+pkgrel=1
+arch=('any')
+pkgdesc="The bind to libgdaex query editor for libzakgtkdecoder (mingw-w64)"
+depends=("${MINGW_PACKAGE_PREFIX}-libgdaex"
+         "${MINGW_PACKAGE_PREFIX}-libzakgtkdecoder")
+makedepends=("${MINGW_PACKAGE_PREFIX}-gcc"
+             "gtk-doc")
+options=('!strip' 'debug' 'staticlibs')
+license=("LGPL 2.1")
+url="http://saetta.ns0.it/"
+source=(git+http://saetta.ns0.it/git/${_realname}
+        001-path.patch)
+sha256sums=('SKIP'
+            '39f186ff5bf8a22c7e214e2c0bdb68d7746197642867ea5f0eda946ad372b62c')
+
+pkgver() {
+  cd "$srcdir/$_realname"
+  printf "%s.%s.%s" "${_base_ver}" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd ${_realname}
+
+  patch -b -V simple -p1 -i ${srcdir}/001-path.patch
+}
+
+build() {
+  mkdir -p build-${MINGW_CHOST}
+  cd build-${MINGW_CHOST}
+
+  ../${_realname}/autogen.sh \
+    --host=${MINGW_CHOST} \
+    --target=${MINGW_CHOST} \
+    --build=${MINGW_CHOST} \
+    --prefix=${MINGW_PREFIX} \
+    --libexecdir=${MINGW_PREFIX}/lib
+  make
+}
+
+package() {
+  cd "$srcdir/build-${MINGW_CHOST}"
+  make DESTDIR=$pkgdir install
+
+  install -Dm644 "${srcdir}/${_realname}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING"
+}