--- /dev/null
+# Maintainer: Andrea Zagli <andrea.zagli.free@gmail.com>
+
+_realname=mm-common
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=0.9.7
+pkgrel=1
+pkgdesc="Common build files of the GNOME C++ bindings (mingw-w64)"
+arch=('any')
+url="http://www.gtkmm.org/"
+license=("GPL 2")
+depends=("${MINGW_PACKAGE_PREFIX}-wget")
+options=(strip staticlibs)
+source=(http://ftp.gnome.org/pub/gnome/sources/${_realname}/${pkgver:0:3}/${_realname}-${pkgver}.tar.xz)
+sha256sums=('78f47336f3bdf034a384c59a39cc9f0d566e69e36aa7c9ee3ec0bb6a94bf8b3e')
+
+prepare() {
+ cd ${_realname}-$pkgver
+
+ autoreconf -fi
+}
+
+build() {
+ [[ -d build-${MINGW_CHOST} ]] && rm -rf build-${MINGW_CHOST}
+ mkdir -p "${srcdir}/build-${MINGW_CHOST}"
+ cd "${srcdir}/build-${MINGW_CHOST}"
+
+ ../${_realname}-${pkgver}/configure \
+ --prefix=${MINGW_PREFIX} \
+ --build=${MINGW_CHOST} \
+ --host=${MINGW_CHOST} \
+ --enable-network
+ make
+}
+
+package() {
+ cd "${srcdir}/build-${MINGW_CHOST}"
+ make DESTDIR="$pkgdir" install
+
+ install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING"
+}