template-glib: nuovo pacchetto wip (richiede glib in testing).

diff --git a/packages/mingw-w64-template-glib-git/PKGBUILD b/packages/mingw-w64-template-glib-git/PKGBUILD
new file mode 100644 (file)
index 0000000..2bfce3a
--- /dev/null
+++ b/packages/mingw-w64-template-glib-git/PKGBUILD
@@ -0,0 +1,54 @@
+# Maintainer: Andrea Zagli <andrea.zagli.free@gmail.com>
+
+_realname=template-glib
+_base_ver=3.19.4
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=3.19.4.30.fea2f7b
+pkgrel=1
+arch=('any')
+pkgdesc="A templating library for GLib (mingw-w64)"
+depends=("${MINGW_PACKAGE_PREFIX}-glib2"
+         "${MINGW_PACKAGE_PREFIX}-gobject-introspection")
+makedepends=("${MINGW_PACKAGE_PREFIX}-gcc"
+             "gtk-doc"
+             "flex"
+             "bison")
+options=('!strip' 'debug' 'staticlibs')
+license=("LGPL 2.1")
+url="http://saetta.ns0.it/"
+source=(git+http://git.gnome.org/browse/${_realname})
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/$_realname"
+  printf "%s.%s.%s" "${_base_ver}" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd ${_realname}
+
+  aclocal --install -I build-aux || exit 1
+  gtkdocize || exit 1
+  autoreconf --force --install -Wno-portability || exit 1
+}
+
+build() {
+  mkdir -p build-${MINGW_CHOST}
+  cd build-${MINGW_CHOST}
+
+  ../${_realname}/configure \
+    --host=${MINGW_CHOST} \
+    --target=${MINGW_CHOST} \
+    --build=${MINGW_CHOST} \
+    --prefix=${MINGW_PREFIX} \
+    --libexecdir=${MINGW_PREFIX}/lib
+  make
+}
+
+package() {
+  cd "$srcdir/build-${MINGW_CHOST}"
+  make DESTDIR=$pkgdir install
+
+  install -Dm644 "${srcdir}/${_realname}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING"
+}